每周一个编程小例子：带反馈的阀门控制程序

剑指工控星期日, 06/22/2025 - 15:02 发表

引言

在工业自动化中，阀门是控制液体或气体流动的关键装置，其开关的状态直接影响生产过程的运行安全与效率。为了确保阀门的可靠操作，阀门控制通常需要结合反馈信号以监控其状态，并在异常情况下进行故障处理。本文将介绍一个基于 PLC（可编程逻辑控制器）的阀门开关控制功能块 ValveSwitchWithFeedback，详细说明其程序逻辑、适用场景及拓展思考。

1 程序代码及介绍

1.1 程序代码

基于西门子的 scl 语言，

FUNCTION_BLOCK "ValveSwitchWithFeedback"
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1   
   VAR_INPUT       
      open : Bool; // 开阀指令      
      close : Bool; // 关阀指令      
      feedBack_open : Bool; // 阀门开到位反馈信号      
      feedBack_close : Bool; // 阀门关到位反馈信号      
      feedBack_open_time : Time := T#2s; // 阀门开反馈最大等待时间      
      feedBack_close_time : Time := T#2s; // 阀门关反馈最大等待时间      
      reset : Bool; // 故障复位信号   
   END_VAR
   
   VAR_OUTPUT       
       Q : Bool; // 阀门当前状态，1为开，0为关      
       OpenError : Bool; // 开阀故障信号      
       CloseError : Bool; // 关阀故障信号   
   END_VAR
   
   VAR      
      staQ : Bool; // 阀门开关状态      
      staOpenError : Bool; // 开阀超时标志      
      staCloseError : Bool; // 关阀超时标志      
      staOpenError_set : Bool; // 开阀故障锁存      
      staCloseError_set : Bool; // 关阀故障锁存      
      IEC_Timer_Open {InstructionName := 'TON_TIME'; LibVersion := '1.0'} : TON_TIME; // 开阀超时定时器      
      IEC_Timer_Close {InstructionName := 'TON_TIME'; LibVersion := '1.0'} : TON_TIME; // 关阀超时定时器   
   END_VAR

BEGIN	
        // 开阀逻辑	
        IF #open AND NOT #close THEN	    
            #staQ := 1;	
        END_IF;	
        #IEC_Timer_Open(IN := #staQ AND NOT #feedBack_open,	                
                        PT := #feedBack_open_time,	                
                        Q => #staOpenError);	
        IF #staOpenError THEN	    
            #staOpenError_set := 1;	
        END_IF;	
        // 关阀逻辑	
        IF #close THEN	    
            #staQ := 0;
        END_IF;	
        #IEC_Timer_Close(IN := NOT #staQ AND NOT #feedBack_close,	                 
                         PT := #feedBack_close_time,	                 
                         Q => #staCloseError);	
        IF #staCloseError THEN	    
            #staCloseError_set := 1;	
        END_IF;	

       // 故障处理：如果故障，则关闭阀门	
        IF #staOpenError_set OR #staCloseError_set THEN	    
            #staQ := 0;	
        END_IF;
	
        // 故障复位逻辑	
        IF #reset THEN	    
            #staOpenError_set := 0;	    
            #staCloseError_set := 0;	
        END_IF;
	
        // 输出赋值	
        #Q := #staQ;	
        #OpenError := #staOpenError_set;	
        #CloseError := #staCloseError_set;

END_FUNCTION_BLOCK

1.2 代码逻辑解析

输入变量：